LYGIA Shader Library

Dependencies:

• lygia/lighting/specular.glsl
• lygia/lighting/diffuse.glsl
• lygia/lighting/shadow.glsl
• lygia/lighting/light/falloff.glsl

Use:

lightPoint(<vec3> _diffuseColor, <vec3> _specularColor, <vec3> _N, <vec3> _V, <float> _NoV, <float> _f0, out <vec3> _diffuse, out <vec3> _specular)

Check it on Github

#ifndef SURFACE_POSITION
#define SURFACE_POSITION vec3(0.0, 0.0, 0.0)
#endif

#ifndef LIGHT_POSITION
#define LIGHT_POSITION  vec3(0.0, 10.0, -50.0)
#endif

#ifndef LIGHT_COLOR
#define LIGHT_COLOR    vec3(0.5, 0.5, 0.5)
#endif

#ifndef LIGHT_INTENSITY
#define LIGHT_INTENSITY 1.0
#endif

#ifndef LIGHT_FALLOFF
#define LIGHT_FALLOFF   0.0
#endif

#ifndef STR_LIGHT_POINT
#define STR_LIGHT_POINT
struct LightPoint {
    vec3    position;
    vec3    color;
    float   intensity;
#ifdef LIGHT_FALLOFF
    float   falloff;
#endif

// Cache
    vec3    direction;
    float   dist;
    float   shadow;
};
#endif

#ifndef FNC_LIGHT_POINT
#define FNC_LIGHT_POINT

void lightPoint(
    const in vec3 _diffuseColor, const in vec3 _specularColor, 
    const in vec3 _V, 
    const in vec3 _Lp, const in vec3 _Ld, const in vec3 _Lc, const in float _Li, const in float _Ldist, const in float _Lof, 
    const in vec3 _N, const in float _NoV, const in float _NoL, const in float _roughness, const in float _f0, 
    inout vec3 _diffuse, inout vec3 _specular) {

    float dif   = diffuse(_Ld, _N, _V, _NoV, _NoL, _roughness);// * INV_PI;
    float spec  = specular(_Ld, _N, _V, _NoV, _NoL, _roughness, _f0);

    vec3 lightContribution = _Lc * _Li;
    #ifdef LIGHT_FALLOFF
    if (_Lof > 0.0)
        lightContribution *= falloff(_Ldist, _Lof);
    #endif

    _diffuse    += max(vec3(0.0), _diffuseColor * lightContribution * dif);
    _specular   += max(vec3(0.0), _specularColor * lightContribution * spec);
}

#ifdef STR_MATERIAL
void lightPoint(
    const in vec3 _diffuseColor, const in vec3 _specularColor,
    LightPoint _L, const in Material _mat, 
    inout vec3 _diffuse, inout vec3 _specular) 
    {
    float f0    = max(_mat.f0.r, max(_mat.f0.g, _mat.f0.b));
    float NoL   = dot(_mat.normal, _L.direction);

    lightPoint( _diffuseColor, _specularColor, 
                _mat.V, 
                _L.position, _L.direction, _L.color, _L.intensity, _L.dist, _L.falloff, 
                _mat.normal, _mat.NoV, NoL, _mat.roughness, f0, 
                _diffuse, _specular);

    // TODO:
    // - make sure that the shadow use a perspective projection
    #ifdef SHADING_MODEL_SUBSURFACE
    vec3  h     = normalize(_mat.V + _L.direction);
    float NoH   = saturate(dot(_mat.normal, h));
    float LoH   = saturate(dot(_L.direction, h));

    float scatterVoH = saturate(dot(_mat.V, -_L.direction));
    float forwardScatter = exp2(scatterVoH * _mat.subsurfacePower - _mat.subsurfacePower);
    float backScatter = saturate(NoL * _mat.thickness + (1.0 - _mat.thickness)) * 0.5;
    float subsurface = mix(backScatter, 1.0, forwardScatter) * (1.0 - _mat.thickness);
    _diffuse += _mat.subsurfaceColor * (subsurface * diffuseLambert());
    #endif
}
#endif

#endif

Dependencies:

• lygia/lighting/specular.glsl
• lygia/lighting/diffuse.glsl
• lygia/lighting/light/falloff.glsl
• lygia/lighting/light/UnityLightingCommon.glsl

Use:

lightPoint(<float3> _diffuseColor, <float3> _specularColor, <float3> _N, <float3> _V, <float> _NoV, <float> _f0, out <float3> _diffuse, out <float3> _specular)

Check it on Github

#ifndef SURFACE_POSITION
#define SURFACE_POSITION float(0.0, 0.0, 0.0)
#endif

#ifndef LIGHT_POSITION
#if defined(UNITY_COMPILER_HLSL)
#define LIGHT_POSITION _WorldSpaceLightPos0.xyz
#else
#define LIGHT_POSITION  float3(0.0, 10.0, -50.0)
#endif
#endif

#ifndef LIGHT_COLOR
#if defined(UNITY_COMPILER_HLSL)
#define LIGHT_COLOR     _LightColor0.rgb
#else
#define LIGHT_COLOR     float3(0.5, 0.5, 0.5)
#endif
#endif

#ifndef LIGHT_INTENSITY
#define LIGHT_INTENSITY 1.0
#endif

#ifndef LIGHT_FALLOFF
#define LIGHT_FALLOFF   0.0
#endif

#ifndef FNC_LIGHT_POINT
#define FNC_LIGHT_POINT

void lightPoint(float3 _diffuseColor, float3 _specularColor, float3 _N, float3 _V, float _NoV, float _roughness, float _f0, float _shadow, inout float3 _diffuse, inout float3 _specular) {
    float3 toLight = LIGHT_POSITION - (SURFACE_POSITION).xyz;
    float toLightLength = length(toLight);
    float3 s = toLight/toLightLength;

    float NoL = dot(_N, s);

    float dif = diffuse(s, _N, _V, _NoV, NoL, _roughness);// * INV_PI;
    float spec = specular(s, _N, _V, _NoV, NoL, _roughness, _f0);

    float3 lightContribution = LIGHT_COLOR * LIGHT_INTENSITY * _shadow;
    #ifdef LIGHT_FALLOFF
    if (LIGHT_FALLOFF > 0.0)
        lightContribution *= falloff(toLightLength, LIGHT_FALLOFF);
    #endif

    _diffuse +=  _diffuseColor * lightContribution * dif;
    _specular += _specularColor * lightContribution * spec;
}

void lightPoint(float3 _diffuseColor, float3 _specularColor, float3 _N, float3 _V, float _NoV, float _roughness, float _f0, inout float3 _diffuse, inout float3 _specular) {
    lightPoint(_diffuseColor, _specularColor, _N, _V,  _NoV, _roughness, _f0, 1.0, _diffuse, _specular);
}

#endif